MediaMonkey forum

Code: Select all

' Gap / Silence Between Songs script v2.1
' By Eyal, 2009.09.16
' By Onno Tabak 2010-04-21 with small part of Gap.vbs by Soren Werk
'
' This script adds an entry in Play menu that let you
' enable/disable a silence time between playing songs.
' Delay time is configurable through Options|Player|SBS.
' Requires MediaMonkey 3.1.0.1218 or newer.
'
' Repeat and Shuffle is accounted for.
' Next song selected before gap
'
' Location: MediaMonkey\Scripts\Auto\SilenceBetweenSongs.vbs
'------------------
Option Explicit

'Set Silence Time in seconds (default = 5):
Dim SilenceTime : SilenceTime = 5
Dim SilenceEnabled : SilenceEnabled = True
Dim GapProgress
Dim GapTimer

Dim AppTitle : AppTitle = "SilenceBetweenSongs"
Dim Version : Version = "2.0"
Dim MenuItem

'------------------
Sub OnStartup
  InitButton
  SilenceBetweenSongs
  InitTimer
End Sub  

Sub InitButton()  
	SDB.IniFile.StringValue(AppTitle,"Version") = Version   '"2.0"

    If Not SDB.IniFile.ValueExists(AppTitle,"Enabled") Then
    	SDB.IniFile.BoolValue(AppTitle,"Enabled") = SilenceEnabled
    End If

    If Not SDB.IniFile.ValueExists(AppTitle,"SilenceTime") Then
    	SDB.IniFile.StringValue(AppTitle,"SilenceTime") = SilenceTime
    End If

    If Not SDB.IniFile.ValueExists(AppTitle,"CrossfadeState") Then
    	SDB.IniFile.BoolValue(AppTitle,"CrossfadeState") = SDB.Player.IsCrossfade
    End If

    SilenceTime = SDB.IniFile.StringValue(AppTitle,"SilenceTime")
    SilenceEnabled = SDB.IniFile.BoolValue(AppTitle,"Enabled")

	Set MenuItem = SDB.UI.AddMenuItem(SDB.UI.Menu_Play,4,2)
    MenuItem.Caption = "Silence between songs"
	Script.RegisterEvent MenuItem, "OnClick", "ToggleSilence"
    MenuItem.Visible = True
	MenuItem.Checked = SilenceEnabled
	
    ' Child of [Player] in the options:
    SDB.UI.AddOptionSheet "Silence between songs", Script.ScriptPath, "InitSheet", "SaveSheet", -2
End Sub

'------------------
Sub ToggleSilence(p)
    SilenceEnabled = Not SilenceEnabled
    MenuItem.Checked = SilenceEnabled
    SDB.IniFile.BoolValue(AppTitle,"Enabled") = SilenceEnabled

    If SilenceEnabled then
        SDB.IniFile.BoolValue(AppTitle,"CrossfadeState") = SDB.Player.IsCrossfade
        SDB.Player.IsCrossfade = False
    Else
        SDB.Player.IsCrossfade = SDB.IniFile.BoolValue(AppTitle,"CrossfadeState")
    End If
    SilenceBetweenSongs    
End Sub

Sub SilenceBetweenSongs
    If SilenceEnabled Then
       Script.RegisterEvent SDB, "OnPlay", "PlayerOnPlay" 
       Script.RegisterEvent SDB, "OnTrackEnd", "PlayerTrackEnd"
    Else
        Script.UnregisterEvents SDB
        SDB.Player.StopAfterCurrent = False
    End If
End Sub

'------------------
Sub InitTimer()
  Set GapTimer = SDB.CreateTimer(1000)
  GapTimer.Enabled = False
  Script.RegisterEvent GapTimer, "OnTimer", "GapOnTimer"
End Sub

'------------------
Sub PlayerOnPlay()
  If SilenceEnabled Then
    SDB.Player.StopAfterCurrent = True
  End If
  If  GapTimer.Enabled = True Then  
    GapTimer.Enabled = False
    Set GapProgress = Nothing
  End If
End Sub

'-----------------------
Sub PlayerTrackEnd()
  If SilenceEnabled and (SDB.Player.CurrentSongIndex+1 < SDB.Player.PlayListCount or SDB.Player.IsRepeat or SDB.Player.IsShuffle) Then
    Set GapProgress = SDB.Progress
    GapProgress.MaxValue = SilenceTime
    GapProgress.Text="Gap " & SilenceTime & " seconds."
    GapTimer.Enabled = True
  Else
    GapTimer.Enabled = False
    Set GapProgress = Nothing
  End If
End Sub

Sub GapOnTimer(Timer)
  If GapProgress.Value = 0 Then
    SDB.Player.Next
  End If
  If GapTimer.Enabled = True Then
    GapProgress.Increase
    GapProgress.Text="Gap " & SilenceTime - GapProgress.Value & " seconds."
  End If
  If GapProgress.Value >= GapProgress.MaxValue Then
    SDB.Player.Play  
    GapTimer.Enabled = False
    Set GapProgress = Nothing
  End If
End Sub

'---------------------
Sub InitSheet(Sheet)
	Dim oPanel1, oCheck1, oSpin1

	With SDB.UI.NewLabel(Sheet)
		.Common.Left = 460
		.Common.Top = 5
		.Caption = "v" & Version
	End With
	
	With SDB.UI.NewLabel(Sheet)
		.Alignment = 2    'Center
		.Common.SetRect 100,30,100,40
		.Caption = "Adds silence between playing songs." & vbcrlf & _
                   "Can also be enabled/disabled through Play menu."
	End With

	Set oPanel1 = SDB.UI.NewGroupBox(Sheet)
	oPanel1.Common.SetRect 100,80,240,100
	oPanel1.Caption = "Delay between songs"

	Set oCheck1 = SDB.UI.NewCheckBox(oPanel1)
	With oCheck1
        .Caption = "Enable"
    	.Common.Left = 25
    	.Common.Top = 25
    	.Common.ControlName = "ChEnable"
        .Checked = SilenceEnabled
    End With
    
     Set oSpin1 = SDB.UI.NewSpinEdit(oPanel1)
     With oSpin1
         .Common.Left = 25
         .Common.Top = 55
         .Common.Width = 45
         .MinValue = 1
         .MaxValue = 15
         .Common.ControlName = "EdLength"
         .Value = SilenceTime
     End With

    With SDB.UI.NewLabel(oPanel1)
        .caption = "second(s)"
        .Common.Left = 80
        .Common.Top = 58
    End With
    
End Sub


'---------------------
Sub SaveSheet(Sheet)
 	Dim v

    Set v = Sheet.Common.ChildControl("ChEnable")
    If v.Checked <> SilenceEnabled then
        ToggleSilence 0
    End If

    'SDB.IniFile.BoolValue(AppTitle,"Enabled") = SilenceEnabled         'Not necessary
    SilenceTime = Sheet.Common.ChildControl("EdLength").Value
    SDB.IniFile.StringValue(AppTitle,"SilenceTime") = SilenceTime
End Sub